home *** CD-ROM | disk | FTP | other *** search
/ Belgian Amiga Club - ADF Collection / BS1 part 19.zip / BS1 part 19 / Lattice C disk 4.adf / source / catch.a < prev    next >
Text File  |  1988-11-07  |  24KB  |  980 lines
  1. * 
  2. * C initial startup procedure under AmigaDOS
  3. *
  4. * Use the following command line to make catch.o
  5. * asm -u -iINCLUDE: catch.a
  6. *
  7. * Use the following command line to make catchres.o
  8. * asm -u -iINCLUDE: -dRESIDENT -ocatchres.o catch.a
  9. *
  10. * Use the following command line to make catchresnr.o
  11. * asm -u -iINCLUDE: -dRESIDENT -dNOREQ -ocatchresnr.o catch.a
  12. *
  13.  
  14.     INCLUDE "exec/types.i"
  15.     INCLUDE "exec/alerts.i"
  16.     INCLUDE "exec/nodes.i"
  17.     INCLUDE "exec/lists.i"
  18.     INCLUDE "exec/ports.i"
  19.     INCLUDE "exec/libraries.i"
  20.     INCLUDE "exec/tasks.i"
  21.  
  22.     INCLUDE "exec/memory.i"
  23.     INCLUDE "exec/execbase.i"
  24.     INCLUDE "libraries/dos.i"
  25.     INCLUDE "libraries/dosextens.i"
  26.     INCLUDE "workbench/startup.i"
  27.     INCLUDE "intuition/intuition.i"
  28.         INCLUDE "exec/funcdef.i"
  29.         INCLUDE "exec/exec_lib.i"
  30.         INCLUDE "libraries/dos_lib.i"
  31.  
  32. VERSION     equ    1
  33. REVISION    equ    0
  34.  
  35. CATCH        set    1
  36.         IFND NOREQ
  37. AUTOREQ     set    1
  38.         ENDC
  39.  
  40.  
  41. MEMFLAGS EQU    MEMF_CLEAR+MEMF_PUBLIC
  42. AbsExecBase EQU 4
  43.  
  44. callsys macro
  45.         CALLLIB _LVO\1
  46.         endm
  47.  
  48.     xdef    XCEXIT                ; exit(code) is standard way to leave C.
  49.     xdef     @XCEXIT
  50.  
  51.     xref    LinkerDB            ; linker defined base value
  52.     xref    _BSSBAS             ; linker defined base of BSS
  53.     xref    _BSSLEN             ; linker defined length of BSS
  54.  
  55.     IFD    RESIDENT
  56.     xref    RESLEN
  57.     xref    RESBASE
  58.     xref    NEWDATAL
  59.     ENDC
  60.  
  61. *    library references
  62.  
  63.         section   text,code
  64.  
  65.     xref    _main            * Name of C program to start with.
  66.     xref    MemCleanup
  67.         xref    __fpinit                * initialize floating point
  68.         xref    __fpterm                * terminate floating point
  69.  
  70. start:
  71.     movem.l d1-d6/a0-a6,-(a7)
  72. REGSIZE EQU    (6+7)*4
  73.     lea    REGSIZE(a7),A5            ; determine old stack pointer
  74.     move.l    a0,a2                ; save command pointer
  75.     move.l    d0,d2                ; and command length
  76.     lea    LinkerDB,a4            ; load base register
  77.     
  78.     IFND    RESIDENT
  79.         lea     _BSSBAS,a3                    * get base of BSS
  80.         moveq   #0,d1
  81.         move.l  #_BSSLEN,d0            * get length of BSS in longwords
  82.         bra.s   clr_lp                 * and clear for length given
  83. clr_bss move.l  d1,(a3)+
  84. clr_lp  dbf     d0,clr_bss
  85.     ENDC
  86.     
  87.     IFD    RESIDENT
  88.     move.l    AbsExecBase.W,a6
  89.         movem.l     d0-d1/a0-a2,-(a7)
  90.     sub.l        #RESBASE,a4
  91.     move.l        #RESLEN,d0
  92.     move.l        #MEMFLAGS,d1
  93.     callsys        AllocMem
  94.     tst.l            d0
  95.     beq.w        abort
  96.     move.l        d0,a0
  97.     move.l        d0,a2
  98. ;a2 now has difference
  99.     move.l        d0,a1
  100.     move.l        #NEWDATAL,d0
  101. ;copy data over
  102. cpy:    move.l        (a4)+,(a0)+
  103.     subq.l        #1,d0
  104.     bne        cpy
  105. ;a4 now points at number of relocs
  106.     move.l        (a4)+,d0
  107. reloc:    beq.s        nreloc
  108.     move.l        a1,a0
  109.     add.l        (a4)+,a0            ; a0 now has add of reloc
  110.     add.l        (a0),a2
  111.     move.l        a2,(a0)
  112.     move.l        a1,a2            ; restore offset
  113.     subq.l        #1,d0
  114.     bra.s        reloc
  115.  
  116. nreloc: move.l        a1,a4            ; set up new base register
  117.     add.l        #RESBASE,a4
  118.         movem.l       (A7)+,d0-d1/a0-a2
  119.     ENDC
  120.  
  121.     move.l    AbsExecBase.W,a6
  122.     move.l    a6,SysBase(A4)
  123.  
  124.     ifd    CATCH
  125.     move.w    AttnFlags(a6),Environment+2(a4) ; save copy for dump
  126.     endc
  127.  
  128.     move.l    a7,_StackPtr(A4)        ; Save stack ptr
  129.     clr.l    WBenchMsg(A4)
  130.  
  131. *------ attempt to open DOS library:
  132.     bsr.w    openDOS
  133.  
  134.     ifd    CATCH
  135.      ifd     AUTOREQ
  136. *------ attempt to open Intuition library:
  137.         bsr.w        openIntui
  138.      endc
  139.     endc
  140.  
  141. *-----  clear any pending signals
  142.     moveq    #0,d0
  143.     move.l    #$00003000,d1
  144.     callsys    SetSignal
  145.  
  146. *------ get the address of our task
  147.     move.l    ThisTask(a6),A3
  148.  
  149.     ifd    CATCH
  150.     move.l    A3,TaskID(a4)
  151.  
  152. *------ initialize exception handler
  153. *------ Remember to preserve the old handler first
  154.         move.l  TC_TRAPDATA(a3),oldtrapdata(A4)
  155.     move.l    TC_TRAPCODE(a3),d0        ; check current exception
  156.         move.l  d0,oldtrapcode(A4)
  157.     swap    d0
  158.     cmpi.w    #$fb,d0             ; see if points to ROM
  159.     ble.s    1$                ; somebody else (debugger?) has vector
  160.     move.l    #Exception,TC_TRAPCODE(a3)    ; install pointers to code
  161.     move.l    a4,TC_TRAPDATA(a3)        ; ...and data
  162. 1$:
  163.     endc
  164.  
  165. *------ are we running as a son of Workbench?
  166.     move.l    pr_CurrentDir(A3),curdir(A4)
  167.     tst.l    pr_CLI(A3)
  168.     beq    fromWorkbench
  169.  
  170. *=======================================================================
  171. *====== CLI Startup Code ===============================================
  172. *=======================================================================
  173. *
  174. * Entry: D2 = command length
  175. *     A2 = Command pointer
  176. fromCLI:
  177.     ifd    CATCH
  178.     moveq    #-1,d0
  179.     move.l    d0,Starter(a4)        ; non-zero means CLI
  180.     move.l    a5,StackTop(a4)
  181.     endc
  182.  
  183.     move.l    a5,D0            ; get top of stack
  184.     sub.l    4(a5),D0        ; compute bottom
  185.     add.l    #128,D0         ; allow for parms overflow
  186.     move.l    D0,_base(A4)        ; save for stack checking
  187.  
  188. *------ find command name:
  189.     move.l    pr_CLI(a3),a0
  190.     add.l    a0,a0        * bcpl pointer conversion
  191.     add.l    a0,a0
  192.     move.l    cli_CommandName(a0),a1
  193.     IFND    AUTOREQ
  194.     move.l    cli_StandardOutput(a0),GConsole(a4)    * save output fh
  195.     ENDC
  196.     add.l    a1,a1        * bcpl pointer conversion
  197.     add.l    a1,a1
  198.  
  199. *------ collect parameters:
  200.     move.l    d2,d0            * get command line length
  201.     moveq.l #0,d1
  202.     move.b    (a1)+,d1
  203.     move.l    a1,_ProgramName(A4)
  204.     add.l    d1,d0            * add length of command name
  205.     addq.l    #1,d0            * allow for space after command
  206.  
  207.     clr.w    -(A7)            * set null terminator for command line
  208.     addq.l    #1,D0            * force to even number of bytes
  209.     andi.w    #$fffe,D0        *(round up)
  210.     sub.l    D0,A7            * make room on stack for command line
  211.     subq.l    #2,D0
  212.  
  213.     clr.w    0(A7,D0)
  214.  
  215. *------ copy command line onto stack
  216.     move.l    d2,d0            * get command line length
  217.     subq.l    #1,d0
  218.     add.l    d1,d2
  219.  
  220. copy_line:
  221.     move.b    0(A2,D0.W),0(A7,D2.W)    * copy command line to stack
  222.     subq.l    #1,d2
  223.     dbf    d0,copy_line
  224.     move.b    #' ',0(a7,d2.w)     * add space between command and parms
  225.     subq.l    #1,d2
  226.  
  227. copy_cmd:
  228.     move.b    0(a1,d2.w),0(a7,d2.w)    * copy command name to stack
  229.     dbf    d2,copy_cmd
  230.     move.l    A7,A1
  231.     move.l    A1,-(A7)        * push command line address
  232.     bra.w    main            * call C entrypoint
  233.  
  234. *=======================================================================
  235. *====== Workbench Startup Code =========================================
  236. *=======================================================================
  237.  
  238. fromWorkbench:
  239.     move.l    TC_SPLOWER(a3),_base(A4)    * set base of stack
  240.         add.l   #128,_base(A4)             * allow for parms overflow
  241.  
  242.     ifd    CATCH
  243.     move.l    TC_SPUPPER(a3),StackTop(a4)    ; set top of stack
  244.     endc
  245.  
  246. *------ we are now set up.  wait for a message from our starter
  247.         lea     pr_MsgPort(A3),a0       * our process base
  248.         callsys WaitPort
  249.         lea     pr_MsgPort(A3),a0       * our process base
  250.         callsys GetMsg
  251.         move.l  d0,WBenchMsg(a4)
  252.         move.l  d0,-(SP)
  253. *
  254.     move.l    d0,a2            * get first argument
  255.     move.l    sm_ArgList(a2),d0
  256.     beq.s    do_cons
  257.     move.l    DOSBase(a4),a6
  258.     move.l    d0,a0
  259.     move.l    wa_Lock(a0),d1
  260.     move.l    d1,curdir(A4)
  261.     callsys    CurrentDir
  262. do_cons:
  263.     move.l    sm_ToolWindow(a2),d1    * get the window argument
  264.     beq.s    do_main
  265.     move.l    #MODE_OLDFILE,d2
  266.     callsys    Open
  267.     move.l    d0,stdin(a4)
  268.     beq.s    do_main
  269.     lsl.l    #2,d0
  270.     move.l    d0,a0
  271.     move.l    fh_Type(a0),pr_ConsoleTask(A3)
  272. do_main:
  273.     move.l    WBenchMsg(A4),a0    * get address of workbench message
  274.     move.l    a0,-(a7)        * push argv
  275.     pea    NULL(a4)        * push argc
  276.     move.l    sm_ArgList(a0),a0    * get address of arguments
  277.     move.l    wa_Name(a0),_ProgramName(A4)    * get name of program
  278.  
  279. *=============================================
  280. *------ common code --------
  281. *=============================================
  282.  
  283. main    jsr     __fpinit(PC)            * Initialize floating point
  284.     jsr    _main(PC)        * call C entrypoint
  285.     moveq.l #0,d0            * set successful status
  286.     bra.s    exit2
  287. *
  288.  
  289. XCEXIT:
  290.     move.l    4(SP),d0    * extract return code
  291. @XCEXIT
  292. exit2:
  293.     move.l    d0,-(a7)
  294.  
  295.     move.l    _ONEXIT(A4),d0    * exit trap function?
  296.     beq.s    exit3
  297.     move.l    d0,a0
  298.     jsr    (a0)
  299. exit3:
  300.     jsr    MemCleanup(PC)        ; cleanup leftover memory alloc.
  301.  
  302.     move.l    AbsExecBase.W,a6
  303.  
  304. *------ Restore the original exception handler
  305.     move.l    ThisTask(a6),A3
  306.         move.l  oldtrapdata(A4),TC_TRAPDATA(a3)
  307.     move.l    oldtrapcode(A4),TC_TRAPCODE(a3)    ; check current exception
  308.  
  309.     move.l    DOSBase(A4),a1
  310.     callsys    CloseLibrary        ; close Dos library
  311.  
  312.     ifd    CATCH
  313.      ifd     AUTOREQ
  314.         move.l    IntuiBase(a4),a1
  315.         callsys        CloseLibrary        ; close Intuition library
  316.      endc
  317.     endc
  318.  
  319.         jsr     __fpterm(PC)            * clean up any floating point
  320.  
  321. done_1c:
  322. *------ if we ran from CLI, skip workbench cleanup:
  323.     tst.l    WBenchMsg(A4)
  324.     beq.s    exitToDOS
  325.     move.l    stdin(A4),d1
  326.     beq.s    done_4
  327.     callsys    Close
  328. done_4:
  329.  
  330. *------ return the startup message to our parent
  331. *    we forbid so workbench can't UnLoadSeg() us
  332. *    before we are done:
  333.     move.l    AbsExecBase.W,A6
  334.     callsys    Forbid
  335.     move.l    WBenchMsg(a4),a1
  336.     callsys    ReplyMsg
  337.  
  338. *------ this rts sends us back to DOS:
  339. exitToDOS:
  340.     IFD    RESIDENT
  341.     move.l    #RESLEN,d0
  342.     move.l    a4,a1
  343.     sub.l    #RESBASE,a1
  344.     move.l    AbsExecBase.W,a6
  345.     callsys    FreeMem
  346.     ENDC
  347.  
  348.  
  349.     
  350.     MOVE.L    (A7)+,D0
  351.     movea.l _StackPtr(a4),SP    * restore stack ptr
  352.     movem.l (a7)+,d1-d6/a0-a6
  353.     rts
  354.  
  355.     IFD    RESIDENT
  356. abort:
  357.         movem.l     (a7)+,d0-d1/a0-a2
  358.     rts
  359.     ENDC
  360.     
  361. *-----------------------------------------------------------------------
  362. noDOS:
  363.         moveq.l #100,d0
  364.         bra.w    exit2
  365.  
  366.  
  367. *-----------------------------------------------------------------------
  368. *    Open the DOS library:
  369.  
  370. openDOS
  371.         lea    DOSName(PC),A1
  372.         moveq.l #0,D0
  373.         callsys    OpenLibrary
  374.         move.l    D0,DOSBase(A4)
  375.         beq.s    noDOS
  376.         rts
  377. DOSName     dc.b    'dos.library',0
  378.  
  379.     ifd    CATCH
  380. *-----------------------------------------------------------------------
  381. *    Open the Intuition library:
  382.  
  383. openIntui:
  384.         lea    IntuiName(PC),A1
  385.         moveq.l #0,D0
  386.         callsys    OpenLibrary
  387.         move.l    D0,IntuiBase(A4)
  388.         beq.s    noDOS
  389.         rts
  390. IntuiName    dc.b    'intuition.library',0
  391.  
  392. *-----------------------------------------------------------------------
  393. *    The Exception Handler - catches GURUs and exits (semi)cleanly
  394. Exception:
  395.     move.l    AbsExecBase.W,a0
  396.     move.l    ThisTask(a0),a0
  397.     move.l    TC_TRAPDATA(a0),a0        ; ...and data
  398.  
  399.     move.l    (a7)+,d0        ; get exception # from stack
  400.     move.l    d0,GURUNum(a0)        ; and save it
  401.     cmpi.l    #3,d0            ; ADDRESS or BUS error?
  402.     bgt.s    2$            ; no, skip adjustment
  403.     btst    #0,Environment+3(a0)    ; is it 68010 or 68020?
  404.     beq.s    1$            ; 0 means NO
  405.     bset    #7,8(a7)        ; set Rerun flag
  406.     bra.s    2$
  407. 1$:
  408.     addq.l    #8,a7            ; adjust for 68000
  409. 2$:
  410.     move.l    2(a7),d0        ; get PC at crash
  411.     move.l    d0,GURUAddr(a0)        ; and save it
  412.     move.l    #GURUExit,2(a7)        ; use our own exit point
  413.     rte
  414.  
  415. *-----------------------------------------------------------------------
  416. *    The Exception exit routine - write 'PGTB' IFF chunk to file
  417. *    'SnapShot.TB' in current directory, then exit to system.
  418.  
  419. GURUExit:
  420.     movem.l d0-d7/a0-a7,-(sp)    ; save all registers
  421.     move.l    AbsExecBase.W,a6    ; make sure we are working with Exec
  422.     callsys    GetCC            ; safe way - works with all CPUs
  423.     move.l    ThisTask(a6),a3
  424.     move.l    TC_TRAPDATA(a3),a4    ; make sure we have a valid # in a4
  425.     move.l    d0,Flags(a4)        ; save area
  426.     movem.l (sp)+,d0-d7
  427.     movem.l d0-d7,DDump(a4)        ; save data reg contents
  428.     movem.l (sp)+,d0-d7
  429.     movem.l d0-d7,ADump(a4)        ; save address reg contents
  430.     tst.l    StackPtr(a4)        ; if there's something there
  431.     bne    GExit1            ; ...we've been here before!
  432.     lea    TempStore(a4),a0    ; calculate addr of TempStore
  433.     move.l    a0,TempAddr(a4)        ; ...and save for later access
  434.     move.l    A7Store(a4),d0        ; make sure we have proper TOS
  435.     move.l    d0,StackPtr(a4)        ; ...and save it
  436.     moveq    #0,d0
  437.     move.l    _ProgramName(a4),a0    ; find length of program name
  438.  
  439.     ifd    AUTOREQ
  440.     move.l    a0,PName(a4)
  441.     endc
  442.  
  443.     subq.l    #1,a0
  444.     move.b    (a0),d0
  445.     addq.l    #4,d0            ; adjust for shift
  446.     lsr.l    #2,d0
  447.     move.l    d0,NameLen(a4)        ; store length
  448.     add.l    d0,FAILlen(a4)        ; and sub-chunk total
  449.  
  450.     moveq    #0,d0            ; clear d0 for use
  451.     lea    VBlankFrequency(a6),a0    ; set up a0 to find correct data
  452.     move.b    (a0)+,d0        ; get just in case
  453.     move.l    d0,VBlankFreq(a4)    ; ...so we can figure what
  454.     move.b    (a0),d0         ; ...type of machine
  455.     move.l    d0,PowerSupFreq(a4)    ; ...we're working on
  456.  
  457.     lea    start-4(pc),a0        ; get seglist ptr
  458.     moveq    #-1,d0            ; always at least 1
  459. 2$:
  460.     addq.l    #1,d0
  461.     move.l    (a0),d1         ; find end of list
  462.     beq.s    3$
  463.     lsl.l    #2,d1            ; BPTR!!!!!
  464.     move.l    d1,a0
  465.     bra.s    2$
  466. 3$:
  467.     add.l    d0,SegCount(a4)     ; store # of seglist pointers
  468.     lsl.l    #1,d0            ; multiply by 2 for longword count
  469.     add.l    d0,FAILlen(a4)        ; and sub-chunk length
  470.  
  471.     move.l    StackTop(a4),d0     ; get top of stack
  472.     sub.l    StackPtr(a4),d0     ; find number of bytes used
  473.     addq.l    #4,d0            ; adjust for longword conversion
  474.     lsr.l    #2,d0            ; convert from bytes to long
  475.     move.l    d0,StackLen(a4)     ; and save
  476.     add.l    d0,s2len(a4)        ; and sub-chunk total
  477.  
  478.     move.l    a5,-(sp)        ; save a5 for later
  479.     callsys    Forbid            ; don't let 'em change while we ask
  480.     move.l    MemList+LH_HEAD(a6),d0    ; first node in MemList
  481. checkchip:
  482.     move.l    d0,a5            ; move node address to address reg
  483.     move.w    MH_ATTRIBUTES(a5),d4    ; get node attributes
  484.     btst    #MEMB_CHIP,d4        ; is it chip?
  485.     beq.s    checkfast        ; no, go on
  486.     lea    chipAvail(a4),a3
  487.     bsr.w    AddIt
  488. checkfast:
  489.     btst    #MEMB_FAST,d4        ; is it fast?
  490.     beq.s    next            ; no, go on
  491.     lea    fastAvail(a4),a3
  492.     bsr.w    AddIt
  493. next:
  494.     move.l    LN_SUCC(a5),d0        ; get address of next node
  495.     bne.s    checkchip        ; ...and loop back if valid
  496.     callsys    Permit            ; allow others access again
  497.     move.l    #MEMF_CHIP+MEMF_LARGEST,d1 ; to find largest hunk in chip ram
  498.     callsys    AvailMem
  499.     move.l    d0,chipLargest(a4)    ; store
  500.     move.l    #MEMF_FAST+MEMF_LARGEST,d1 ; to find largest hunk in fast ram
  501.     callsys    AvailMem
  502.     move.l    d0,fastLargest(a4)    ; store
  503.     move.l    (sp)+,a5        ; and restore a5
  504.  
  505.     ifd    AUTOREQ
  506.     moveq    #0,d0            ; PosFlag
  507.     move.l    d0,d1            ; NegFlag
  508.     move.l    d0,a0            ; 0 means use current window
  509.     lea    IText1(a4),a1        ; Body Text
  510.     lea    IText5(a4),a2        ; Positive Gadget Text
  511.     lea    IText6(a4),a3        ; Negative Gadget Text
  512.     moveq    #1,d2
  513.     lsl.l    #8,d2            ; quick way to set Width
  514.     moveq    #76,d3            ; Height
  515.     move.l    IntuiBase(a4),a6    ; get intuition library pointer
  516.     jsr    -$15c(A6)        ; callsys    AutoRequest
  517.     move.l    AbsExecBase.W,a6
  518.     tst.l    d0            ; save SnapShot?
  519.     beq.s    GExit2            ; no, just exit
  520.     endc
  521.  
  522.     move.l    DOSBase(a4),a6
  523.     lea    DumpName(a4),a0     ; get name of output file
  524.     move.l    a0,d1
  525.     move.l    #MODE_NEWFILE,d2    ; create new file
  526.     callsys    Open
  527.     bne.s    4$
  528.     lea    DumpPath(a4),a0     ; if error in current dir, try DF1:
  529.     move.l    a0,d1
  530.     move.l    #MODE_NEWFILE,d2
  531.     callsys    Open
  532.     bne.s    4$
  533.     move.b    #'0',DumpPath+3(a4)    ; still error?    Try DF0:
  534.     lea    DumpPath(a4),a0
  535.     move.l    a0,d1
  536.     move.l    #MODE_NEWFILE,d2
  537.     callsys    Open
  538.  
  539.     ifnd    AUTOREQ
  540.     bne.s    4$            ; if no error, continue (finally!)
  541.     move.l    GConsole(a4),d1
  542.     beq.w    GExit2
  543.     lea    failmsg(a4),a0
  544.     move.l    a0,d2
  545.     move.l    #23,d3
  546.     callsys    Write
  547.     endc
  548.  
  549.     bra.w    GExit2            ; else, print msg & DIE gracefully
  550. 4$:
  551.     move.l    d0,d5            ; save file handle for Write
  552.     move.l    d0,fp(a4)        ; ...and in a safe place for later
  553.     move.l    d5,d1            ; get file handle
  554.     lea    PGTB(a4),a0        ; first part of fixed
  555.     move.l    a0,d2
  556.     move.l    #chunk_len_1,d3     ; length of first
  557.     callsys    Write            ; ...since it gets written over
  558.  
  559.     move.l    d5,d1            ; get file handle
  560.     move.l    _ProgramName(a4),d2    ; get address of program name
  561.     move.l    NameLen(a4),d3        ; get # longs in program name
  562.     lsl.l    #2,d3            ; ..and convert to bytes
  563.     callsys    Write
  564.  
  565.     move.l    d5,d1            ; get file handle
  566.     lea    Environment(a4),a0    ; second part of fixed
  567.     move.l    a0,d2
  568.     move.l    #chunk_len_2,d3     ; length of second part
  569.     callsys    Write
  570.  
  571.     lea    start-8(pc),a0        ; address of seglist (size of seg)
  572.     move.l    (a0)+,d0        ; segsize
  573.     move.l    d0,TempStore+4(a4)    ; save it
  574.     move.l    a0,TempStore(a4)    ; store first number
  575.     move.l    SegCount(a4),d4
  576. 5$:
  577.     move.l    d5,d1            ; get file handle
  578.     move.l    TempAddr(a4),d2     ; address of write buffer
  579.     moveq    #TempSize,d3        ; size of segment pointer
  580.     callsys    Write
  581.     move.l    TempStore(a4),a0    ; retrieve pointer
  582.     move.l    (a0),d0         ; get next seg pointer
  583.     lsl.l    #2,d0            ; adjust
  584.     move.l    d0,TempStore(a4)    ; ..and save
  585.     move.l    d0,a0
  586.     move.l    -4(a0),d0        ; get segsize
  587.     move.l    d0,TempStore+4(a4)    ; ...and save it
  588.     subq.l    #1,d4            ; done yet?
  589.     bne.s    5$            ; no, do next
  590.  
  591.     tst.l    _FMEM(a4)        ; do they want memory reported?
  592.     beq.s    55$            ; no, forget it
  593.     move.l    d5,d1
  594.     lea    subFMEM(a4),a0
  595.     move.l    a0,d2
  596.     move.l    #FMEMlen,d3
  597.     callsys    Write
  598.  
  599. 55$:
  600.     move.l    d5,d1            ; (get the idea?)
  601.     lea    subREGS(a4),a0        ; third part of fixed
  602.     move.l    a0,d2
  603.     move.l    #chunk_len_3,d3     ; length of third
  604.     callsys    Write
  605.  
  606.     move.l    StackLen(a4),d0     ; get length of stack used
  607.     cmpi.l    #2048,d0        ; > 8k ?
  608.     bgt.s    6$            ; yes, dump two chunks
  609.     move.l    d5,d1
  610.     lea    STAK2(a4),a0        ; whole stack chunk
  611.     move.l    a0,d2
  612.     moveq    #STAK2len,d3        ; length of fixed part
  613.     callsys    Write
  614.  
  615.     move.l    d5,d1
  616.     move.l    StackPtr(a4),d2     ; address of stack
  617.     move.l    StackLen(a4),d3     ; get # longwords on stack
  618.     lsl.l    #2,d3            ; ..and convert to bytes
  619.     callsys    Write
  620.     bra.s    7$
  621. 6$:
  622.     move.l    d5,d1
  623.     lea    STAK3(a4),a0        ; top4k chunk
  624.     move.l    a0,d2
  625.     moveq    #STAK3len,d3        ; length of fixed part
  626.     callsys    Write
  627.  
  628.     move.l    d5,d1
  629.     move.l    StackTop(a4),d2     ; find top of stack
  630.     sub.l    #4096,d2        ; find top-4k
  631.     move.l    #4096,d3        ; # bytes to write
  632.     callsys    Write
  633.  
  634.     move.l    d5,d1
  635.     lea    STAK4(a4),a0        ; bottom4k chunk
  636.     move.l    a0,d2
  637.     moveq    #STAK4len,d3        ; length of fixed part
  638.     callsys    Write
  639.  
  640.     move.l    d5,d1
  641.     move.l    StackPtr(a4),d2     ; current stack address
  642.     move.l    #4096,d3        ; # bytes to write
  643.     callsys    Write
  644. 7$:
  645.     move.l    _STAKOffset(a4),d3
  646.     beq.s    8$
  647.     lsr.l    #2,d3
  648.     addq.l    #1,d3
  649.     move.l    d3,_STAKOffset(a4)
  650.     addq.l    #1,d3
  651.     move.l    d5,d1
  652.     lea    STAK5(a4),a0
  653.     move.l    a0,d2
  654.     moveq    #STAK5len,d3
  655.     callsys    Write
  656.  
  657.     move.l    d5,d1
  658.     move.l    StackPtr(a4),d2
  659.     move.l    _STAKOffset(a4),d3
  660.     subq.l    #1,d3
  661.     move.l    StackLen(a4),d4
  662.     cmp.l    d3,d4
  663.     bge.s    75$
  664.     move.l    StackLen(a4),d3
  665. 75$:
  666.     lsl.l    #2,d3
  667.     callsys    Write
  668. 8$:
  669.     tst.l    _ONGURU(A4)        ; user GURU function?
  670.     beq.s    9$
  671.     move.l    d5,-(sp)
  672.     move.l    d5,d1
  673.     lea    UDAT(a4),a0
  674.     move.l    a0,d2
  675.     move.l    #UDATlen,d3
  676.     callsys    Write
  677.     move.l    d5,d1
  678.     moveq    #0,d2            ; zero offset
  679.     moveq    #1,d3            ; ...from EOF
  680.     callsys    Seek
  681.     move.l    d0,SeekStore(a4)
  682.     move.l    _ONGURU(a4),a0
  683.     jsr    (a0)
  684.     addq.l    #4,sp
  685. 9$:
  686.     move.l    fp(a4),d5
  687.     move.l    d5,d1
  688.     moveq    #0,d2            ; offset from EOF
  689.     moveq    #1,d3            ; OFFSET_END
  690.     callsys    Seek            ; Seek returns OLD position
  691.     move.l    d0,d1
  692.     andi.l    #3,d1            ; did user write even longwords?
  693.     beq.s    10$            ; Yep!    Nice Human.
  694.     move.l    d1,d6            ; Nope, save for later.
  695.     clr.l    TempStore(a4)        ; clear temp storage
  696.     move.l    d5,d1
  697.     move.l    TempAddr(a4),d2
  698.     moveq    #4,d3
  699.     sub.l    d6,d3            ; find how many NULLs to pad
  700.     callsys    Write
  701.     bra.s    9$
  702. 10$:
  703.     tst.l    SeekStore(a4)        ; did we write UDAT?
  704.     beq.s    11$            ; nope!
  705.     sub.l    SeekStore(a4),d0    ; find length of UDAT section
  706.     lsr.l    #2,d0            ; adjust to longwords
  707.     move.l    d0,TempStore(a4)    ; save UDAT length for write
  708.     move.l    d5,d1
  709.     move.l    SeekStore(a4),d2    ; find where to write it
  710.     subq.l    #4,d2
  711.     moveq    #-1,d3            ; OFFSET_BEGINNING
  712.     callsys    Seek
  713.     move.l    d5,d1
  714.     move.l    TempAddr(a4),d2
  715.     move.l    #4,d3
  716.     callsys    Write            ; write length of UDAT field to file
  717. 11$:
  718.     move.l    d5,d1
  719.     moveq    #0,d2            ; offset to 'Length' field
  720.     moveq    #1,d3            ; OFFSET_END
  721.     callsys    Seek            ; make sure we are at end of file
  722.     move.l    d5,d1
  723.     moveq    #4,d2            ; offset to 'Length' field
  724.     moveq    #-1,d3            ; OFFSET_BEGINNING
  725.     callsys    Seek
  726.     subq.l    #8,d0            ; adjust total length
  727.     lsr.l    #2,d0            ; adjust to longwords
  728.     move.l    d0,TempStore(a4)    ; save for write
  729.     move.l    d5,d1
  730.     move.l    TempAddr(a4),d2
  731.     move.l    #4,d3
  732.     callsys    Write            ; write 'Length' field
  733. GExit1:
  734.     move.l    fp(a4),d1
  735.     beq.s    GExit2
  736.     move.l    DOSBase(a4),a6
  737.     callsys    Close
  738.  
  739.     ifnd    AUTOREQ
  740.     move.l    GConsole(a4),d1
  741.     beq.s    GExit2
  742.     lea    success(a4),a0
  743.     move.l    a0,d2
  744.     move.l    #32,d3
  745.     callsys    Write
  746.     endc
  747. GExit2:
  748.     move.l    TaskID(a4),a6
  749.     move.l    AbsExecBase.W,a6
  750.     moveq    #$47,d0
  751.     bra.w    exit2
  752.  
  753. *-----------------------------------------------------------------------
  754. * AddIt:    routine to add memory parts to variables
  755.  
  756. AddIt:
  757.     move.l    MH_FREE(a5),d0
  758.     add.l    d0,(a3)         ; add to available
  759.     move.l    MH_UPPER(a5),d0
  760.     sub.l    MH_LOWER(a5),d0
  761.     add.l    d0,4(a3)        ; add to Max section
  762.     rts
  763.     endc
  764.  
  765.         
  766.         section   __MERGED,DATA
  767. *
  768.     xref    DOSBase
  769.  
  770.     xdef    NULL,SysBase,WBenchMsg
  771.     xdef    curdir,_mbase,_mnext,_msize,_tsize
  772.     xdef    _oserr,_OSERR,_FPERR,_SIGFPE,_ONERR,_ONEXIT,_ONBREAK
  773.     xdef    _SIGINT
  774.     xdef    _ProgramName,_StackPtr,_base
  775.  
  776.     ifd    CATCH
  777.     xdef    _ONGURU,_FMEM,_STAKOffset
  778.     endc
  779. *
  780. NULL        dc.l    0        *
  781. _base        dc.l    0        * base of stack
  782. _mbase        dc.l    0        * base of memory pool
  783. _mnext        dc.l    0        * next available memory location
  784. _msize        dc.l    0        * size of memory pool
  785. _tsize        dc.l    0        * total size?
  786. _oserr:
  787. _OSERR        dc.l    0
  788. _FPERR        dc.l    0
  789. _SIGFPE     dc.l    0
  790. _SIGINT     dc.l    0
  791. _ONERR        dc.l    0
  792. _ONEXIT     dc.l    0
  793. _ONBREAK    dc.l    0
  794. curdir        dc.l    0
  795. SysBase     dc.l    0
  796. WBenchMsg    dc.l    0
  797. oldtrapcode     dc.l    0
  798. oldtrapdata     dc.l    0
  799. _StackPtr    dc.l    0
  800. stdin        dc.l    0
  801. _ProgramName    dc.l    0
  802.  
  803.     ifd    CATCH
  804. _ONGURU     dc.l    0
  805. IntuiBase    dc.l    0
  806. TaskID        dc.l    0
  807.     ifnd    AUTOREQ
  808. GConsole    dc.l    0
  809. failmsg     dc.b    7,'Can''t write SnapShot!',10
  810. success     dc.b    7,'GURU caught; SnapShot written!',10
  811.     endc
  812.     cnop    0,4
  813. _FMEM        dc.l    0
  814. fp        dc.l    0        ; save SnapShot file pointer
  815. DumpPath    dc.b    'DF1:'
  816. DumpName    dc.b    'SnapShot.TB',0
  817. SeekStore    dc.l    0
  818. TempAddr    dc.l    0        ; Storage for &TempStore
  819. TempStore    dc.l    0,0        ; Temporary storage for BPTR -> APTR
  820. TempSize    equ    *-TempStore
  821.  
  822.     cnop    0,4
  823.     ifd    AUTOREQ
  824. TAttr:                ; Text attributes for font
  825.     dc.l    TName        ; name of font
  826.     dc.w    TOPAZ_EIGHTY    ; font size
  827.     dc.b    FS_NORMAL    ; font style
  828.     dc.b    FPF_ROMFONT    ; font preferences
  829. TName:
  830.     dc.b    'topaz',0
  831.     cnop    0,4
  832.  
  833. IText1:             ; Text definitions for AutoReq call
  834.     dc.b    3,0,RP_JAM1,0    ; front & back pens, drawmode and filler byte
  835.     dc.w    6,4        ; XY origin relative to container TopLeft
  836.     dc.l    TAttr        ; font pointer or NULL for default
  837.     dc.l    ITextText1    ; pointer to text
  838.     dc.l    IText2        ; next IntuiText structure
  839. ITextText1:
  840.     dc.b    'Program:',0
  841.     cnop 0,4
  842. IText2:
  843.     dc.b    3,0,RP_JAM1,0
  844.     dc.w    78,4
  845.     dc.l    TAttr
  846. PName    dc.l    0
  847.     dc.l    IText3
  848.     cnop    0,4
  849. IText3:
  850.     dc.b    3,0,RP_JAM1,0
  851.     dc.w    55,16
  852.     dc.l    TAttr
  853.     dc.l    ITextText3
  854.     dc.l    IText4
  855. ITextText3:
  856.     dc.b    'I caught a GURU!',0
  857.     cnop 0,4
  858. IText4:
  859.     dc.b    3,0,RP_JAM1,0
  860.     dc.w    20,28
  861.     dc.l    TAttr
  862.     dc.l    ITextText4
  863.     dc.l    NULL
  864. ITextText4:
  865.     dc.b    'Should I make a SnapShot?',0
  866.     cnop 0,4
  867. IText5:
  868.     dc.b    3,0,RP_JAM1,0
  869.     dc.w    6,4
  870.     dc.l    TAttr
  871.     dc.l    ITextText5
  872.     dc.l    NULL
  873. ITextText5:
  874.     dc.b    'YES',0
  875.     cnop 0,4
  876. IText6:
  877.     dc.b    3,0,RP_JAM1,0
  878.     dc.w    7,4
  879.     dc.l    TAttr
  880.     dc.l    ITextText6
  881.     dc.l    NULL
  882. ITextText6:
  883.     dc.b    'NO',0
  884.     endc
  885.  
  886.     cnop 0,4
  887.  
  888. *--------------------------------------------------------------------------
  889. * New IFF chunk format -
  890. *    PGTB = Program Traceback, header for chunk
  891. *    FAIL = reason for and environment of crash
  892. *    REGS = registers at time of crash, including PC and CCR
  893. *    VERS = version, revision, name of this program
  894. *    STAK = ENTIRE stack at time of crash or, alternately,
  895. *        the top and bottom 4k if the stack used is > 8k
  896. *    UDAT = optional user data dump (if _ONGURU is set to a
  897. *        function pointer in the user's program)
  898. *--------------------------------------------------------------------------
  899.  
  900. PGTB        dc.b    'PGTB'
  901. Length        dc.l    0        ; length of chunk (in longwords)
  902.  
  903. subFAIL     dc.b    'FAIL'
  904. FAILlen     dc.l    9
  905. NameLen     dc.l    0        ; length of program name
  906. chunk_len_1    equ    *-PGTB
  907. Environment    dc.l    0        ; CPU (, Math)
  908. VBlankFreq    dc.l    0        ;    PAL = 50, NTSC = 60 (approx.)
  909. PowerSupFreq    dc.l    0        ; Europe = 50,    USA = 60 (approx.)
  910. Starter     dc.l    0        ; 0 = WB, -1 = CLI
  911. GURUNum     dc.l    0        ; cause of crash (GURU #)
  912. SegCount    dc.l    1        ; # hunks in seglist
  913. chunk_len_2    equ    *-Environment
  914.  
  915. subFMEM     dc.b    'FMEM'        ; FMEM - free memory at crash
  916.         dc.l    6
  917. chipAvail    dc.l    0        ; available chip memory
  918. chipMax     dc.l    0        ;    maximum    chip memory
  919. chipLargest    dc.l    0        ;    largest    chip memory
  920. fastAvail    dc.l    0        ; available fast memory
  921. fastMax     dc.l    0        ;    maximum    fast memory
  922. fastLargest    dc.l    0        ;    largest    fast memory
  923. FMEMlen     equ    *-subFMEM
  924.  
  925. subREGS     dc.b    'REGS'        ; REGS - register storage field
  926. REGSlen     dc.l    18
  927. GURUAddr    dc.l    0        ; PC at time of crash
  928. Flags        dc.l    0        ; Condition Code Register (CCR)
  929. DDump        dc.l    0,0,0,0,0,0,0,0 ; data registers
  930. ADump        dc.l    0,0,0,0,0,0,0    ; address registers
  931. A7Store     dc.l    0
  932.  
  933. subVERS     dc.b    'VERS'        ; VERS - program version field
  934.         dc.l    6
  935.         dc.l    VERSION     ; version #
  936.         dc.l    REVISION    ; revision #
  937.         dc.l    3        ; length of name of program
  938.         IFD    RESIDENT
  939.         dc.b    'catchres.o',0,0 ; name
  940.         ENDC
  941.         IFND    RESIDENT
  942.         dc.b    'catch.o   ',0,0 ; name
  943.         ENDC
  944.  
  945. subSTAK     dc.b    'STAK'        ; STAK - stack field
  946. STAKlen     dc.l    4
  947. Type        dc.l    0        ; 0 = Info
  948. StackTop    dc.l    0        ; top of stack pointer
  949. StackPtr    dc.l    0        ; current Stack Pointer
  950. StackLen    dc.l    0        ; # bytes used on stack
  951. chunk_len_3    equ    *-subREGS
  952.  
  953. STAK2        dc.b    'STAK'
  954. s2len        dc.l    1        ; length of subtype
  955.         dc.l    1        ; 1 = whole stack
  956. STAK2len    equ    *-STAK2
  957.  
  958. STAK3        dc.b    'STAK'
  959.         dc.l    1025
  960.         dc.l    2        ; 2 = top 4k of stack
  961. STAK3len    equ    *-STAK3
  962.  
  963. STAK4        dc.b    'STAK'
  964.         dc.l    1025
  965.         dc.l    3        ; 3 = bottom 4k of stack
  966. STAK4len    equ    *-STAK4
  967.  
  968. STAK5        dc.b    'STAK'
  969. _STAKOffset    dc.l    0
  970.         dc.l    4        ; 4 = user defined amount
  971. STAK5len    equ    *-STAK5
  972.  
  973. UDAT        dc.b    'UDAT'
  974.         dc.l    0
  975. UDATlen     equ    *-UDAT
  976.     endc
  977.  
  978.     END
  979.  
  980.